ESP8266-WROOM-02 Proxy経由でWEBページを取得

ESP8266HTTPClientを使ってあげれば
httpであればProxy経由で取得するのは簡単でした。
httpsは一筋縄ではいかなそう(?)勉強中です。

単純なサンプルを載せておきます。

/*
 * 単純にProxy経由でWEBページを取得するサンプル
 */

#include <ESP8266WiFi.h>
#include <ESP8266HTTPClient.h>

void setup() {
  Serial.begin(115200);
  Serial.println();

  WiFi.mode(WIFI_STA);
  WiFi.begin("SSID", "PASSWORD");

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  Serial.println();
  Serial.println("WiFi connected");  
  Serial.print("IP address: ");
  Serial.println(WiFi.localIP());
}

void loop() {
    // wait for WiFi connection
    if((WiFi.status() == WL_CONNECTED)) {

        HTTPClient http;

        Serial.print("[HTTP] begin...\n");

        //Proxyサーバを使う場合
        http.begin("Proxy.server.ip",8080,"http://www.dmsk.com/pc/main-hw.html");

        //Proxyサーバを使わない場合
        //http.begin("http://www.dmsk.com/pc/main-hw.html");
        
        Serial.print("[HTTP] GET...\n");
        // start connection and send HTTP header
        int httpCode = http.GET();

        // httpCode will be negative on error
        if(httpCode > 0) {
            // HTTP header has been send and Server response header has been handled
            Serial.printf("[HTTP] GET... code: %d\n", httpCode);

            // file found at server
            if(httpCode == HTTP_CODE_OK) {
                String payload = http.getString();
                Serial.println(payload);
            }
        } else {
            Serial.printf("[HTTP] GET... failed, error: %s\n", http.errorToString(httpCode).c_str());
        }

        http.end();
    }

    delay(20000);
}

解説というほどのこともないですが、
35行目で、Proxyサーバのアドレス、ポート、開きたいページのURLを指定するだけです。

ESP-WROOM-02 TCPソケット通信

ESP-WROOM-02を2個使って片方がサーバ、もう片方がクライアントとして接続し、TCPソケット通信をしてみます。
UDPのサンプルは良く見るけど、TCPのソケット通信はなかなか見つからなかったので実験をかねて作成してみました。
クライアント側を電池で動かせばリモコンとして使えそうです。



概要:
・Arduinoの開発環境でプログラミングしてESP-WROOM-02に書込む
・サーバ側はSoftAPモードでWiFiアクセスポイントを開設
・クライアント側はSWを押すとコマンドをサーバに送る
・サーバ側は送られて来たコマンドを見てLEDをON/OFFする

 

動作イメージ

クライアント側のSWを押すとサーバ側のLEDが光ります

 

サーバ側回路図とプログラム


//サーバ側プログラム
#include <ESP8266WiFi.h>

static const char *SSID = "WROOM-B'MICOM";
static const char *PASSWD = "password";

const int LED1 = 12; //SW1のIOピン
const int LED2 = 16; //SW2のIOピン
const int LED3 = 5;  //SW3のIOピン
const int LED4 = 4;  //SW4のIOピン

IPAddress ip(192, 168, 0, 33);
//IPAddress gateway(192, 168, 0, 1);
//IPAddress netmask(255, 255, 255, 0);

WiFiServer server(26842);  //Port番号

void setup() {
  Serial.begin(115200);
  Serial.println();

  pinMode(LED1, OUTPUT);
  pinMode(LED2, OUTPUT);
  pinMode(LED3, OUTPUT);
  pinMode(LED4, OUTPUT);

  //起動時LEDを光らせてみる
  digitalWrite(LED1, HIGH);
  delay(100);
  digitalWrite(LED1, LOW);
  digitalWrite(LED2, HIGH);
  delay(100);
  digitalWrite(LED2, LOW);
  digitalWrite(LED3, HIGH);
  delay(100);
  digitalWrite(LED3, LOW);
  digitalWrite(LED4, HIGH);
  delay(100);
  digitalWrite(LED4, LOW);

  //WiFiアクセスポイントを開始
  WiFi.mode(WIFI_AP);
  WiFi.softAP(SSID, PASSWD);
  WiFi.softAPConfig(ip, WiFi.gatewayIP(), WiFi.subnetMask());
  //WiFi.softAPConfig(ip, gateway, netmask);
  WiFi.begin();

  IPAddress myIP = WiFi.softAPIP();
  Serial.print("AP Started. myIP address: ");
  Serial.println(myIP);

  //Portのlistenを開始
  server.begin();
  Serial.println("Server started");

}

void loop() {
  String cmd;
  cmd = rcvCommand();

  //受信したコマンドに対応したLEDを点灯/消灯
  if(cmd == "LED1OFF"){
    Serial.print("Exec: ");
    Serial.println(cmd);
    digitalWrite(LED1, LOW);
  }
  if(cmd == "LED1ON"){
    Serial.print("Exec: ");
    Serial.println(cmd);
    digitalWrite(LED1, HIGH);
  }
  if(cmd == "LED2OFF"){
    Serial.print("Exec: ");
    Serial.println(cmd);
    digitalWrite(LED2, LOW);
  }
  if(cmd == "LED2ON"){
    Serial.print("Exec: ");
    Serial.println(cmd);
    digitalWrite(LED2, HIGH);
  }
  if(cmd == "LED3OFF"){
    Serial.print("Exec: ");
    Serial.println(cmd);
    digitalWrite(LED3, LOW);
  }
  if(cmd == "LED3ON"){
    Serial.print("Exec: ");
    Serial.println(cmd);
    digitalWrite(LED3, HIGH);
  }
  if(cmd == "LED4OFF"){
    Serial.print("Exec: ");
    Serial.println(cmd);
    digitalWrite(LED4, LOW);
  }
  if(cmd == "LED4ON"){
    Serial.print("Exec: ");
    Serial.println(cmd);
    digitalWrite(LED4, HIGH);
  }
}

//コマンドを受信してそのコマンド文字列を返す
String rcvCommand(){
  WiFiClient client = server.available();
  String rstr;
  if (client.connected()) {
    Serial.println("Connected to client");

    //コマンド文字列受信(文字列が来なければタイムアウトする)
    rstr = client.readStringUntil('\r');
    Serial.print("[");
    Serial.print(rstr);
    Serial.println("]");

    //応答送信
    client.print("OK\r");

    //接続をクローズ
    client.stop();
    Serial.println("Closed");
  }

  return rstr;
}




クライアント側回路図とプログラム


//クライアント側プログラム
#include <ESP8266WiFi.h>
#include <Ticker.h>

#define SW_ONDELAY  4000  //SWチャタリング防止ディレイ(ループカウント数)
#define SW_OFFDELAY 4000  //SWチャタリング防止ディレイ(ループカウント数)

Ticker ticker1;  //タイマ割り込み (LED点滅用)

const char* ssid = "WROOM-B'MICOM";
const char* password = "password";

char hostIP[] = "192.168.0.33";
int  hostPort = 26842;

const int SW1 = 12; //SW1のIOピン
const int SW2 = 16; //SW2のIOピン
const int SW3 = 5;  //SW3のIOピン
const int SW4 = 4;  //SW4のIOピン
const int LED = 13; //LEDのIOピン

int ledStatus = 0; //0:消灯 1:点灯 2:点滅 
int sw1Status = 0; //0:OFF 1:ON
int sw2Status = 0; //0:OFF 1:ON
int sw3Status = 0; //0:OFF 1:ON
int sw4Status = 0; //0:OFF 1:ON

WiFiClient client;

void setup() {
  Serial.begin(115200);

  //タイマ割り込み間隔と 割り込み関数名 LEDの点滅に使用
  ticker1.attach_ms(500, ticker1_interrupt);

  pinMode(SW1, INPUT);
  pinMode(SW2, INPUT);
  pinMode(SW3, INPUT);
  pinMode(SW4, INPUT);
  pinMode(LED, OUTPUT);
    
  Serial.println("Booting...");
  WiFi.mode(WIFI_STA);

  connectToWiFi();
  
}

void connectToWiFi(){
    ledStatus = 2;//0:消灯 1:点灯 2:点滅 
    
    WiFi.begin(ssid, password);
    delay(500);

    int retrycnt = 0;
    while(WiFi.waitForConnectResult() != WL_CONNECTED){
      Serial.print(".");
      delay(100);
      retrycnt++;
      if(retrycnt > 100){
        ESP.restart();
      }
    }
    Serial.println("Connect Success");
}


void loop() {

  if (WiFi.status() == WL_CONNECTED) {
    ledStatus = 1;//0:消灯 1:点灯 2:点滅 

    sw1process();
    sw2process();
    sw3process();
    sw4process();
    
  }else{
    //WiFi接続が切れた
    Serial.println("WiFi ERR. Restart.");
    ESP.restart();
  }
}

void sendSocket(String str)
{
  if (client.connect(hostIP, hostPort))
  { 
    Serial.print("Connected:");
    Serial.println(hostIP);
    Serial.println("Posting: " + str);

    //送信
    client.print(str);
 
    //応答受信
    client.setTimeout(1000);
    do{
      String line = client.readStringUntil('\r');
      Serial.print(line);
    } while (client.available() != 0);  //残りがあるときはさらに受信のためループ
    Serial.println();
  }
  else
  {
     Serial.println("Connection failed.");
  }
}

//SW1の処理
int sw1onCnt = 0;
int sw1offCnt = 0;
void sw1process(){
  if(sw1Status == 0){
    if(digitalRead(SW1) == HIGH){
      sw1onCnt++;
      if(sw1onCnt == SW_ONDELAY){
        //ON送信
        sendSocket("LED1ON\r");;
        sw1Status = 1;
        sw1offCnt = 0;
      }else if(sw1onCnt > SW_ONDELAY){
        sw1onCnt = SW_ONDELAY;
      }
    }else{
      sw1onCnt = 0;
    }    
  }else{
    if(digitalRead(SW1) == LOW){
      sw1offCnt++;
      if(sw1offCnt == SW_OFFDELAY){
        //OFF送信
        sendSocket("LED1OFF\r");
        sw1Status = 0;
        sw1onCnt = 0;
      }else if(sw1offCnt > SW_OFFDELAY){
        sw1offCnt = SW_OFFDELAY;
      }
    }else{
      sw1offCnt = 0;
    } 
  }
}

//SW2の処理
int sw2onCnt = 0;
int sw2offCnt = 0;
void sw2process(){
  if(sw2Status == 0){
    if(digitalRead(SW2) == HIGH){
      sw2onCnt++;
      if(sw2onCnt == SW_ONDELAY){
        //ON送信
        sendSocket("LED2ON\r");;
        sw2Status = 1;
        sw2offCnt = 0;
      }else if(sw2onCnt > SW_ONDELAY){
        sw2onCnt = SW_ONDELAY;
      }
    }else{
      sw2onCnt = 0;
    }    
  }else{
    if(digitalRead(SW2) == LOW){
      sw2offCnt++;
      if(sw2offCnt == SW_OFFDELAY){
        //OFF送信
        sendSocket("LED2OFF\r");
        sw2Status = 0;
        sw2onCnt = 0;
      }else if(sw2offCnt > SW_OFFDELAY){
        sw2offCnt = SW_OFFDELAY;
      }
    }else{
      sw2offCnt = 0;
    } 
  }
}

//SW3の処理
int sw3onCnt = 0;
int sw3offCnt = 0;
void sw3process(){
  if(sw3Status == 0){
    if(digitalRead(SW3) == HIGH){
      sw3onCnt++;
      if(sw3onCnt == SW_ONDELAY){
        //ON送信
        sendSocket("LED3ON\r");;
        sw3Status = 1;
        sw3offCnt = 0;
      }else if(sw3onCnt > SW_ONDELAY){
        sw3onCnt = SW_ONDELAY;
      }
    }else{
      sw3onCnt = 0;
    }    
  }else{
    if(digitalRead(SW3) == LOW){
      sw3offCnt++;
      if(sw3offCnt == SW_OFFDELAY){
        //OFF送信
        sendSocket("LED3OFF\r");
        sw3Status = 0;
        sw3onCnt = 0;
      }else if(sw3offCnt > SW_OFFDELAY){
        sw3offCnt = SW_OFFDELAY;
      }
    }else{
      sw3offCnt = 0;
    } 
  }
}

//SW4の処理
int sw4onCnt = 0;
int sw4offCnt = 0;
void sw4process(){
  if(sw4Status == 0){
    if(digitalRead(SW4) == HIGH){
      sw4onCnt++;
      if(sw4onCnt == SW_ONDELAY){
        //ON送信
        sendSocket("LED4ON\r");;
        sw4Status = 1;
        sw4offCnt = 0;
      }else if(sw4onCnt > SW_ONDELAY){
        sw4onCnt = SW_ONDELAY;
      }
    }else{
      sw4onCnt = 0;
    }    
  }else{
    if(digitalRead(SW4) == LOW){
      sw4offCnt++;
      if(sw4offCnt == SW_OFFDELAY){
        //OFF送信
        sendSocket("LED4OFF\r");
        sw4Status = 0;
        sw4onCnt = 0;
      }else if(sw4offCnt > SW_OFFDELAY){
        sw4offCnt = SW_OFFDELAY;
      }
    }else{
      sw4offCnt = 0;
    } 
  }
}


//タイマ割り込み時の処理
void ticker1_interrupt(){
  if(ledStatus == 0){
    digitalWrite(LED, LOW);
  }else if(ledStatus == 1){
    digitalWrite(LED, HIGH);
  }else if(ledStatus == 2){
    digitalWrite(LED, !digitalRead(LED));
  }
}

3DSの連射機を作ってみた やっすいやつやん

Nintendo 3DSでボタンを連打したいときってありますよね。ドラクエのカジノのスロットとかドラクエのカジノのスロットとか。Youtubeとか見ているとLEGOとかモーターの回転とかで連打するように工夫している方もいらっしゃるようですが、ここで解説するのはアマゾンで買えるやっすいソレノイドを使ったバージョンっていう感じのものです。他に使ってる材料もそこらへんに転がっているものばかりなので皆さんも興味を持っていただけたら参考にしてください。

ソレノイドって何?
↑こんなやつです。
ソレノイドとは、電気を流すと中の棒が動く電磁石を利用した電気部品で、これを使って電気をオン・オフして中の棒を動かし、それでボタンを連打しようという魂胆。
実際に私が買ったソレノイドはアマゾンで317円。安い!

とりあえず、動画にしてみたので、ここに貼っておきます。ソレノイドの動きがどんなもんかわかるかと。。。

電気のオン・オフを自動でやらせたいので、こちらもアマゾンで格安で手に入るArduino Nano互換品を使用します。

↑こんな感じのです。これもアマゾンで400円前後

 

では実際に回路を考えてみます。

考えてみました…。


上記回路図のコメント
・電源はACアダプタでとる
・ソレノイドの定格が12V1Aなのでそれ相当のACアダプタを用意
(こっそり言うと、そんなACアダプタないよって人は昔の重いトランスタイプのACアダプタなら表示以上の電流が出たりするのでそういうのを使うのも手かもです)
・回路図ではトランジスタを使っていますが、FETやフォトカプラのほうが良いかもしれません。今回は、とりあえずそこらへんにあって使えそうなものを採用しました。

実際に部品を用意して基板にハンダしてみました。

続いてArduinoのプログラムを書いて行きます。
Arduinoの開発環境は公式ページから無料でダウンロードできますし、ブラウザ上で開発するWEB EDITORもあります。

詳しくは、解説しているサイトが沢山あるのでググりましょう(๑´ڡ`๑)テヘペロ

それでは実際にArduino Nano(互換品)に書込んで見ます。以下のプログラムをArduino IDEにコピペしてコンパイル、書き込みをしてみてください。

//ソレノイド連射Arduino Nanoプログラム

int statusmode = 0; //0:連射OFF 1:連射ON
int swcount=0;      //SWのチャタリング防止用カウンタ

void setup() {
  // シリアルポートを9600bpsで初期化
  Serial.begin(9600);
  
  pinMode(2, OUTPUT);  //ソレノイドへ出力
  pinMode(12, INPUT);  //SW入力
  pinMode(13, OUTPUT); //LED出力
}

void loop() {
  int val ;
  int inputchar;

  //プッシュSW入力処理
  //プッシュSW入力トグルで切替え(連射中/停止中)
  if(digitalRead(12)==HIGH){
    swcount++;
  }else{
    swcount=0;  
  }
  if(swcount>100){
    swcount=0;      
    if(statusmode==0){ 
      statusmode=1;
    }else if(statusmode==1){ 
      statusmode=0;
    }
  }
 
  //SW入力以外にもパソコンから
  //USBシリアル通信で's'で連射開始、'f'で連射停止も可能
  inputchar = Serial.read();
  switch(inputchar){
    case 's'://start
      statusmode = 1;
      break;
    case 'f'://finish
      statusmode = 0;
      break;
  }

  // 半固定抵抗からの読込み値(連射の速度をアナログで変更)
  val = analogRead(0) ; 

  //ソレノイドのオン・オフ処理
  if(statusmode == 0){
    digitalWrite(13,LOW);
  }else if(statusmode == 1){
    digitalWrite(13,HIGH);  
    digitalWrite(2, HIGH);
    delay(100);
    digitalWrite(13,LOW);
    digitalWrite(2, LOW);
    delay(val);
  }
}